# Maintainer: Tim Falken <tim@timfalken.com>
pkgname=bluegit
pkgver=0.1.0
pkgrel=1
pkgdesc='Self-hosted git-platform voor git.timfalken.com'
arch=('x86_64')
url='https://git.timfalken.com'
license=('MIT')
depends=('git' 'docker')
makedepends=('go')
backup=('etc/bluegit/config.yml')
options=('!debug')

build() {
  local root
  root="$(cd "$startdir/../.." && pwd)"
  cd "$root"
  export CGO_ENABLED=0
  # go.mod vraagt Go 1.26; een oudere Arch-go haalt die toolchain zelf op.
  export GOTOOLCHAIN=auto
  export GOFLAGS='-trimpath'
  go build -ldflags='-s -w' -o "$srcdir/bluegit" ./cmd/bluegit
}

package() {
  local root
  root="$(cd "$startdir/../.." && pwd)"
  install -Dm755 "$srcdir/bluegit" "$pkgdir/usr/bin/bluegit"
  install -Dm644 "$root/packaging/bluegit.service" "$pkgdir/usr/lib/systemd/system/bluegit.service"
  install -Dm644 "$root/packaging/bluegit.yml" "$pkgdir/etc/bluegit/config.yml"
  install -Dm644 "$root/packaging/storage.conf" "$pkgdir/usr/share/bluegit/storage.conf.example"
  install -Dm644 "$root/packaging/sysusers.conf" "$pkgdir/usr/lib/sysusers.d/bluegit.conf"
  install -Dm644 "$root/packaging/tmpfiles.conf" "$pkgdir/usr/lib/tmpfiles.d/bluegit.conf"
  install -Dm755 "$root/packaging/bluegit-update.sh" "$pkgdir/usr/lib/bluegit/update"
  install -Dm644 "$root/packaging/bluegit-update.service" "$pkgdir/usr/lib/systemd/system/bluegit-update.service"
  install -Dm644 "$root/packaging/bluegit-update.rules" "$pkgdir/usr/share/polkit-1/rules.d/49-bluegit-update.rules"
}
