plugins {
    java
    id("com.gradleup.shadow") version "9.3.1"
}

group = "nl.timfalken"
version = "1.0.12"

repositories {
    mavenCentral()
    maven("https://repo.papermc.io/repository/maven-public/")
    maven("https://repo.codemc.io/repository/maven-releases/")
    maven("https://repo.codemc.io/repository/maven-snapshots/")
}

dependencies {
    compileOnly("io.papermc.paper:paper-api:26.2.build.+")

    // Bundled into ChestPreview by shadowJar. Adventure stays on Paper's classpath;
    // relocating net.kyori is what broke embedded PacketEvents on load.
    implementation("com.github.retrooper:packetevents-spigot:2.13.0") {
        exclude(group = "net.kyori")
    }
}

java {
    toolchain.languageVersion.set(JavaLanguageVersion.of(25))
}

tasks.jar {
    enabled = false
}

tasks.shadowJar {
    archiveClassifier.set("")
    archiveFileName.set("ChestPreview-${project.version}.jar")

    // Same relocation as ContainerPipes: only PacketEvents itself. Paper already
    // ships Adventure and Gson; relocating those breaks PacketEvents on load.
    relocate("com.github.retrooper.packetevents", "nl.timfalken.chestpreview.libs.packetevents.api")
    relocate("io.github.retrooper.packetevents", "nl.timfalken.chestpreview.libs.packetevents.impl")

    // PacketEvents embeds bStats in the Spigot implementation. Keep our private copy private too.
    relocate("org.bstats", "nl.timfalken.chestpreview.libs.bstats")

    mergeServiceFiles()

    // Intentionally do NOT call minimize(): PacketEvents warns this can cause classloading issues.
}

tasks.assemble {
    dependsOn(tasks.shadowJar)
}

tasks.build {
    dependsOn(tasks.shadowJar)
}
