# Maintainer: posprint contributors
pkgname=posprint
pkgver=0.5.7
pkgrel=1
pkgdesc="Designer for POS-print documents with live preview and USB ESC/POS printing"
arch=('x86_64')
url="https://git.timfalken.com/timfa/posprint"
license=('MIT')
conflicts=('posprint-bin')
depends=(
  'gcc-libs'
  'libxkbcommon'
  'libxcb'
  'openssl'
  'dbus'
  'wayland'
  'libx11'
  'fontconfig'
  'freetype2'
  'libglvnd'
)
makedepends=('rust' 'cargo' 'pkgconf' 'git')
# !debug: recent makepkg.conf enables debug split packages; those scramble
# CI globs (posprint-*.pkg.tar.zst) and are not shipped as release assets.
options=('!lto' '!debug')
source=()
sha256sums=()

prepare() {
  local root="$startdir/../.."
  mkdir -p "$srcdir/$pkgname-$pkgver"
  rsync -a \
    --exclude target \
    --exclude .git \
    --exclude packaging/arch/pkg \
    --exclude packaging/arch/src \
    --exclude 'packaging/arch/*.pkg.tar.zst' \
    --exclude 'packaging/arch/*.pkg.tar.zst.sig' \
    "$root/" "$srcdir/$pkgname-$pkgver/"
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  cargo build --release --locked
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  install -Dm755 target/release/posprint "$pkgdir/usr/bin/posprint"
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
  install -Dm644 packaging/posprint.desktop "$pkgdir/usr/share/applications/posprint.desktop"
  install -Dm644 packaging/posprint-url.desktop "$pkgdir/usr/share/applications/posprint-url.desktop"
  install -Dm644 packaging/mime/posprint.xml "$pkgdir/usr/share/mime/packages/posprint.xml"
  install -Dm644 packaging/linux/posprint-print.desktop "$pkgdir/usr/share/kio/servicemenus/posprint-print.desktop"
  install -Dm644 packaging/linux/posprint-print-thunar.xml "$pkgdir/usr/share/thunar/uca/posprint-print.xml"
  install -Dm644 pos-logo.png "$pkgdir/usr/share/pixmaps/posprint.png"
}
