BlueGit

timfa bluegit

Files

bluegit / packaging / aur-backup / PKGBUILD

PKGBUILD

PKGBUILD 1.8 KiB Download Raw
1# Maintainer: Tim Falken <tim@timfalken.com>
2pkgname=bluegit-backup
3pkgver=20261115000000
4pkgrel=1
5pkgdesc='Backup server for a BlueGit instance: incremental copy, archives, rollback'
6arch=('x86_64' 'aarch64')
7url='https://git.timfalken.com/timfa/bluegit-backup'
8license=('MIT')
9depends=('curl')
10makedepends=('go')
11backup=('etc/bluegit-backup/config.yml')
12options=('!debug')
13install=bluegit-backup.install
14_commit=0000000000000000000000000000000000000000
15source=("bluegit-backup-${_commit}.tar.gz::https://git.timfalken.com/timfa/bluegit-backup/-/archive/${_commit}/bluegit-backup-${_commit}.tar.gz")
16sha256sums=('SKIP')
17
18build() {
19 cd "$srcdir/bluegit-backup-${_commit}"
20 export CGO_ENABLED=0
21 export GOTOOLCHAIN=auto
22 export GOFLAGS='-trimpath'
23 export GOCACHE="${BUILDDIR:-$srcdir}/gocache"
24 export GOPATH="${BUILDDIR:-$srcdir}/gopath"
25 go build -ldflags="-s -w -X git.timfalken.com/timfa/bluegit-backup/internal/server.Version=${pkgver}" -o bluegit-backup ./cmd/bluegit-backup
26}
27
28package() {
29 cd "$srcdir/bluegit-backup-${_commit}"
30 install -Dm755 bluegit-backup "$pkgdir/usr/bin/bluegit-backup"
31 install -Dm644 packaging/bluegit-backup.service "$pkgdir/usr/lib/systemd/system/bluegit-backup.service"
32 install -Dm644 packaging/config.yml "$pkgdir/etc/bluegit-backup/config.yml"
33 install -Dm644 packaging/sysusers.conf "$pkgdir/usr/lib/sysusers.d/bluegit-backup.conf"
34 install -Dm644 packaging/tmpfiles.conf "$pkgdir/usr/lib/tmpfiles.d/bluegit-backup.conf"
35 install -Dm755 packaging/bluegit-backup-update.sh "$pkgdir/usr/lib/bluegit-backup/update"
36 install -Dm644 packaging/bluegit-backup-update.service "$pkgdir/usr/lib/systemd/system/bluegit-backup-update.service"
37 install -Dm644 packaging/bluegit-backup-update.rules "$pkgdir/usr/share/polkit-1/rules.d/49-bluegit-backup-update.rules"
38 install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
39}