BlueGit

timfa bluegit

Files

bluegit / packaging / aur-backup / PKGBUILD

PKGBUILD

PKGBUILD 1.4 KiB Download Raw
1# Maintainer: Tim Falken <tim@timfalken.com>
2pkgname=bluegit-backup
3pkgver=20261115000000
4pkgrel=1
5pkgdesc='Backup server for a BlueGit instance: incremental copy, archives, rollback'
6arch=('x86_64' 'aarch64')
7url='https://git.timfalken.com/timfa/bluegit'
8license=('MIT')
9makedepends=('go')
10options=('!debug')
11install=bluegit-backup.install
12_commit=0000000000000000000000000000000000000000
13source=("bluegit-${_commit}.tar.gz::https://git.timfalken.com/timfa/bluegit/-/archive/${_commit}/bluegit-${_commit}.tar.gz")
14sha256sums=('SKIP')
15
16build() {
17 cd "$srcdir/bluegit-${_commit}"
18 export CGO_ENABLED=0
19 export GOTOOLCHAIN=auto
20 export GOFLAGS='-trimpath'
21 export GOCACHE="${BUILDDIR:-$srcdir}/gocache"
22 export GOPATH="${BUILDDIR:-$srcdir}/gopath"
23 go build -ldflags="-s -w -X gitlab.com/Timfa/bluegit/internal/backupserver/server.Version=${pkgver}" -o bluegit-backup ./cmd/bluegit-backup
24}
25
26package() {
27 cd "$srcdir/bluegit-${_commit}"
28 install -Dm755 bluegit-backup "$pkgdir/usr/bin/bluegit-backup"
29 install -Dm644 packaging/backup/bluegit-backup.service "$pkgdir/usr/lib/systemd/system/bluegit-backup.service"
30 install -Dm644 packaging/backup/sysusers.conf "$pkgdir/usr/lib/sysusers.d/bluegit-backup.conf"
31 install -Dm644 packaging/backup/tmpfiles.conf "$pkgdir/usr/lib/tmpfiles.d/bluegit-backup.conf"
32 install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
33}