BlueGit

timfa chestpreviews

Files

chestpreviews / build.gradle.kts

build.gradle.kts

chore: bump version to 1.0.12
timfa GitLab CI · pushed by timfa · 2 months ago
6d6d6896 History
build.gradle.kts 1.6 KiB Download Raw
1plugins {
2 java
3 id("com.gradleup.shadow") version "9.3.1"
4}
5
6group = "nl.timfalken"
7version = "1.0.12"
8
9repositories {
10 mavenCentral()
11 maven("https://repo.papermc.io/repository/maven-public/")
12 maven("https://repo.codemc.io/repository/maven-releases/")
13 maven("https://repo.codemc.io/repository/maven-snapshots/")
14}
15
16dependencies {
17 compileOnly("io.papermc.paper:paper-api:26.2.build.+")
18
19 // Bundled into ChestPreview by shadowJar. Adventure stays on Paper's classpath;
20 // relocating net.kyori is what broke embedded PacketEvents on load.
21 implementation("com.github.retrooper:packetevents-spigot:2.13.0") {
22 exclude(group = "net.kyori")
23 }
24}
25
26java {
27 toolchain.languageVersion.set(JavaLanguageVersion.of(25))
28}
29
30tasks.jar {
31 enabled = false
32}
33
34tasks.shadowJar {
35 archiveClassifier.set("")
36 archiveFileName.set("ChestPreview-${project.version}.jar")
37
38 // Same relocation as ContainerPipes: only PacketEvents itself. Paper already
39 // ships Adventure and Gson; relocating those breaks PacketEvents on load.
40 relocate("com.github.retrooper.packetevents", "nl.timfalken.chestpreview.libs.packetevents.api")
41 relocate("io.github.retrooper.packetevents", "nl.timfalken.chestpreview.libs.packetevents.impl")
42
43 // PacketEvents embeds bStats in the Spigot implementation. Keep our private copy private too.
44 relocate("org.bstats", "nl.timfalken.chestpreview.libs.bstats")
45
46 mergeServiceFiles()
47
48 // Intentionally do NOT call minimize(): PacketEvents warns this can cause classloading issues.
49}
50
51tasks.assemble {
52 dependsOn(tasks.shadowJar)
53}
54
55tasks.build {
56 dependsOn(tasks.shadowJar)
57}