BlueGit

timfa posprint

Files

posprint / packaging / arch / PKGBUILD

PKGBUILD

PKGBUILD 1.9 KiB Download Raw
1# Maintainer: posprint contributors
2pkgname=posprint
3pkgver=0.5.7
4pkgrel=1
5pkgdesc="Designer for POS-print documents with live preview and USB ESC/POS printing"
6arch=('x86_64')
7url="https://git.timfalken.com/timfa/posprint"
8license=('MIT')
9conflicts=('posprint-bin')
10depends=(
11 'gcc-libs'
12 'libxkbcommon'
13 'libxcb'
14 'openssl'
15 'dbus'
16 'wayland'
17 'libx11'
18 'fontconfig'
19 'freetype2'
20 'libglvnd'
21)
22makedepends=('rust' 'cargo' 'pkgconf' 'git')
23# !debug: recent makepkg.conf enables debug split packages; those scramble
24# CI globs (posprint-*.pkg.tar.zst) and are not shipped as release assets.
25options=('!lto' '!debug')
26source=()
27sha256sums=()
28
29prepare() {
30 local root="$startdir/../.."
31 mkdir -p "$srcdir/$pkgname-$pkgver"
32 rsync -a \
33 --exclude target \
34 --exclude .git \
35 --exclude packaging/arch/pkg \
36 --exclude packaging/arch/src \
37 --exclude 'packaging/arch/*.pkg.tar.zst' \
38 --exclude 'packaging/arch/*.pkg.tar.zst.sig' \
39 "$root/" "$srcdir/$pkgname-$pkgver/"
40}
41
42build() {
43 cd "$srcdir/$pkgname-$pkgver"
44 cargo build --release --locked
45}
46
47package() {
48 cd "$srcdir/$pkgname-$pkgver"
49 install -Dm755 target/release/posprint "$pkgdir/usr/bin/posprint"
50 install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
51 install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
52 install -Dm644 packaging/posprint.desktop "$pkgdir/usr/share/applications/posprint.desktop"
53 install -Dm644 packaging/posprint-url.desktop "$pkgdir/usr/share/applications/posprint-url.desktop"
54 install -Dm644 packaging/mime/posprint.xml "$pkgdir/usr/share/mime/packages/posprint.xml"
55 install -Dm644 packaging/linux/posprint-print.desktop "$pkgdir/usr/share/kio/servicemenus/posprint-print.desktop"
56 install -Dm644 packaging/linux/posprint-print-thunar.xml "$pkgdir/usr/share/thunar/uca/posprint-print.xml"
57 install -Dm644 pos-logo.png "$pkgdir/usr/share/pixmaps/posprint.png"
58}